BindingCollection

一个Binding对象的集合。

语法

BindingCollection

说明

BindingCollection对象允许把任意的数据供应程序绑定到任意的数据使用者。要把使用者绑定到数据供应程序，使用Add方法向该集合添加一个Binding对象。每一个Binding对象代表一个特定的使用者到BindingCollection对象提供的DataSource的绑定。

没有设计时界面的数据源，例如一个配置为数据源的Class（通过设置它的DataSourceBehavior属性为VbDataSource），或者一个ADO Recordset，可以在运行时使用BindingObject集合来绑定。

使用标准的集合语法返回或设置集合成员的属性。

Binding对象、BindingCollection 对象示例

本例使用BindingCollection对象把一个数据源绑定到两个TextBox控件。首先打开一个ADODB记录集对象，然后设置BindingCollection的DataSource属性为该记录集。随后，程序代码把两个Binding对象添加到该集合，同时也就把这两个TextBox控件绑定到该记录集的不同字段了。

要试验该例，在“引用...”对话框设置对Microsoft Data Binding Collection的引用。在同一个对话框中，设置对Microsoft ActiveX Data Objects Library的引用。在窗体上绘制两个TextBox控件，把代码粘贴到“声明”部分。按F5键，并单击窗体移动到记录集的下一条记录。

Option Explicit

Private colBndNwind As New BindingCollection

Private rsNwind As New ADODB.Recordset

Private cn As New ADODB.Connection

Private Sub Form_Load()

' 设置Connection对象参数。

With cn

' 下列的连接在您的计算机上可能能够正常工作，也可能不能正常工作。

' 请改变它以定位Nwind.mdb文件。

' 该文件包括在Visual Basic中。

.Provider = "Microsoft.Jet.OLEDB.3.51"

.Open "C:Program FilesDevStudioVBNwind.mdb"

End With

' 打开该记录集对象。

rsNwind.Open "Select * From Products", cn

' 设置Bindings集合的DataSource为该记录集。

Set colBndNwind.DataSource = rsNwind

' 添加到Bindings集合。

With colBndNwind

.Add Text1, "Text", "ProductName", , "product"

.Add Text2, "Text", "SupplierID", , "ID"

End With

' 打印集合中对象的属性。

Dim bndObj As Binding

For Each bndObj In colBndNwind

Debug.Print "DataField", "PropertyName", "Key"

Debug.Print bndObj.DataField, bndObj.PropertyName, bndObj.Key

Debug.Print

Next

End Sub

Private Sub Form_Click()

' 单击窗体移动到下一条记录。

rsNwind.MoveNext

End Sub